[new-package] avogadroapp 1.99.0

Author: MehdiChinoune

mingw-w64-avogadroapp/001-fix-build-on-mingw.patch

@@ -0,0 +1,39 @@
+--- a/avogadro/CMakeLists.txt
++++ b/avogadro/CMakeLists.txt
+@@ -67,7 +67,7 @@
+   FILES_MATCHING PATTERN "*.qm"
+ )
+ 
+-if(APPLE OR WIN32 OR INSTALL_BUNDLE_FILES)
++if(APPLE OR MSVC OR INSTALL_BUNDLE_FILES)
+ # copy the qt translation files
+ get_filename_component(_qttranslationdir "${Qt5_DIR}/../../../translations" ABSOLUTE)
+ message(STATUS "Install Qt translations ${_qttranslationdir}")
+@@ -181,7 +181,7 @@
+ add_executable(avogadro WIN32 MACOSX_BUNDLE
+   ${avogadro_srcs} ${ui_srcs} ${rcc_srcs})
+ target_link_libraries(avogadro Qt::Widgets Qt::Network Qt::Concurrent)
+-if(WIN32)
++if(MSVC)
+   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /NODEFAULTLIB:MSVCRTD")
+ if(QT_VERSION EQUAL 5)
+   target_link_libraries(avogadro Qt::WinMain)
+--- a/avogadro/lastinstall/CMakeLists.txt
++++ b/avogadro/lastinstall/CMakeLists.txt
+@@ -1,4 +1,4 @@
+-if((APPLE OR WIN32) AND NOT ${CMAKE_VERSION} VERSION_LESS 2.8.8)
++if((APPLE OR MSVC) AND NOT ${CMAKE_VERSION} VERSION_LESS 2.8.8)
+   set(pfx "")
+   if(NOT APPLE)
+     set(pfx "bin/")
+--- a/cmake/AvogadroCPack.cmake
++++ b/cmake/AvogadroCPack.cmake
+@@ -36,7 +36,7 @@
+ 
+ # Should we add extra install rules to make a self-contained bundle, this is
+ # usually only required when attempting to create self-contained installers.
+-if(APPLE OR WIN32)
++if(APPLE OR MSVC)
+   set(INSTALL_BUNDLE_FILES ON)
+ else()
+   option(INSTALL_BUNDLE_FILES "Add install rules to bundle files" OFF)

mingw-w64-avogadroapp/PKGBUILD

@@ -0,0 +1,66 @@
+# Contributor: Mehdi Chinoune <[email protected]>
+
+_realname=avogadroapp
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=1.99.0
+pkgrel=1
+pkgdesc='Advanced molecular editor designed for cross-platform use in computational chemistry, molecular modeling, bioinformatics, materials science, and related areas (mingw-w64)'
+arch=(any)
+mingw_arch=(ucrt64 clang64 clangarm64)
+url='https://www.openchemistry.org/'
+msys2_repository_url="https://github.com/OpenChemistry/avogadroapp"
+license=(spdx:BSD-3-Clause)
+depends=("${MINGW_PACKAGE_PREFIX}-avogadrolibs"
+         "${MINGW_PACKAGE_PREFIX}-avogadrolibs-qt6"
+         "${MINGW_PACKAGE_PREFIX}-molequeue"
+         "${MINGW_PACKAGE_PREFIX}-qt6-5compat"
+         "${MINGW_PACKAGE_PREFIX}-qt6-base")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
+             "${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-eigen3"
+             "${MINGW_PACKAGE_PREFIX}-vtk"
+             "${MINGW_PACKAGE_PREFIX}-fast_float"
+             "${MINGW_PACKAGE_PREFIX}-utf8cpp")
+source=(https://github.com/OpenChemistry/avogadroapp/archive/${pkgver}/${_realname}-${pkgver}.tar.gz
+        https://github.com/OpenChemistry/avogadro-i18n/archive/${pkgver}/avogadro-i18n-${pkgver}.tar.gz
+        001-fix-build-on-mingw.patch)
+sha256sums=('4713faa4e755433947924a381fd1631dfe46a9f27065765cfa04c120ed603189'
+            '0ca56e3ffd065f4981f2d5185c6de13fa7b9f6e78e98e9e3014ed9512d7c80ae'
+            'dd4f67e8f80ca96f024a142831ef1ba5cd6c57dca6590230a44b9268e6302508')
+
+prepare() {
+  mv avogadro-i18n-${pkgver} avogadro-i18n
+
+  cd ${_realname}-${pkgver}
+  patch -p1 -i "${srcdir}"/001-fix-build-on-mingw.patch
+}
+
+build() {
+  declare -a _extra_config
+  if check_option "debug" "n"; then
+    _extra_config+=("-DCMAKE_BUILD_TYPE=Release")
+  else
+    _extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
+  fi
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  ${MINGW_PREFIX}/bin/cmake \
+    -GNinja \
+    -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+    -DCMAKE_DLL_NAME_WITH_SOVERSION=ON \
+    "${_extra_config[@]}" \
+    -DAvogadro_ENABLE_RPC=OFF \
+    -DUSE_VTK=ON \
+    -DQT_VERSION=6 \
+    -B build-${MSYSTEM} \
+    -S ${_realname}-${pkgver}
+
+  ${MINGW_PREFIX}/bin/cmake --build build-${MSYSTEM}
+}
+
+package() {
+  DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake --install build-${MSYSTEM}
+
+  install -Dm644 ${_realname}-${pkgver}/LICENSE -t "${pkgdir}"${MINGW_PREFIX}/share/licenses/${_realname}
+}