Add Data::Medium::load_track_durations in place of view join

751b58f changed the medium data layer
to always perform a join againt the new medium_track_durations view, but
this unfortunately leads to a very poorly optimized query plan:

https://gist.github.com/mwiencek/8f117c96e244213f28333551c753cdd4

I've partially reverted that commit and introduced a
load_track_durations method to query the view separately from the main
query, which is optimized as expected.

Author: mwiencek

lib/MusicBrainz/Server/Controller/CDTOC.pm

@@ -127,6 +127,7 @@ sub set_durations : Chained('load') PathPart('set-durations') Edit
             message => l('Could not find medium')
         );
 
+    $c->model('Medium')->load_track_durations($medium);
     $c->model('Release')->load($medium);
 
     $c->model('Track')->load_for_mediums($medium);
@@ -378,6 +379,7 @@ sub move : Local Edit
         ) unless $medium->may_have_discids;
 
         $c->model('Medium')->load($medium_cdtoc);
+        $c->model('Medium')->load_track_durations($medium_cdtoc->medium);
 
         $c->model('Track')->load_for_mediums($medium);
         $c->model('Recording')->load($medium->all_tracks);

lib/MusicBrainz/Server/Controller/Release.pm

@@ -145,6 +145,7 @@ sub discids : Chained('load') {
     my @medium_cdtocs = $c->model('MediumCDTOC')->load_for_mediums($release->all_mediums);
     $c->model('CDTOC')->load(@medium_cdtocs);
     $c->model('Medium')->load(@medium_cdtocs);
+    $c->model('Medium')->load_track_durations(map { $_->medium } @medium_cdtocs);
     $c->stash( has_cdtocs => scalar(@medium_cdtocs) > 0 );
 }
 

lib/MusicBrainz/Server/Data/Medium.pm

@@ -18,14 +18,13 @@ use Scalar::Util qw( weaken );
 
 sub _table
 {
-    return 'medium LEFT JOIN medium_track_durations mtd ON mtd.medium = medium.id';
+    return 'medium';
 }
 
 sub _columns
 {
     return 'medium.id, release, position, format, medium.name,
             medium.edits_pending, track_count,
-            mtd.pregap_length, mtd.cdtoc_track_lengths, mtd.data_track_lengths,
             COALESCE((SELECT true FROM track WHERE medium = medium.id AND position = 0), false) AS has_pregap,
             (SELECT count(*) FROM track WHERE medium = medium.id AND position > 0 AND is_data_track = false) AS cdtoc_track_count';
 }
@@ -47,9 +46,6 @@ sub _column_mapping
         edits_pending       => 'edits_pending',
         has_pregap          => 'has_pregap',
         cdtoc_track_count   => 'cdtoc_track_count',
-        cdtoc_track_lengths => 'cdtoc_track_lengths',
-        data_track_lengths  => 'data_track_lengths',
-        pregap_length       => 'pregap_length',
     };
 }
 
@@ -64,6 +60,32 @@ sub load
     return load_subobjects($self, 'medium', @objs);
 }
 
+sub load_track_durations {
+    my ($self, @mediums) = @_;
+
+    @mediums = grep { !$_->durations_loaded } @mediums;
+    return unless @mediums;
+
+    my %id_to_medium = object_to_ids(@mediums);
+    my @ids = keys %id_to_medium;
+    return unless @ids;
+
+    my $query =
+        'SELECT medium, pregap_length, cdtoc_track_lengths, data_track_lengths ' .
+        'FROM medium_track_durations ' .
+        'WHERE medium = any(?)';
+
+    my $duration_rows = $self->sql->select_list_of_hashes($query, [\@ids]);
+    for my $row (@$duration_rows) {
+        for my $medium (@{ $id_to_medium{ $row->{medium} } }) {
+            $medium->pregap_length($row->{pregap_length});
+            $medium->cdtoc_track_lengths($row->{cdtoc_track_lengths});
+            $medium->data_track_lengths($row->{data_track_lengths});
+            $medium->durations_loaded(1);
+        }
+    }
+}
+
 sub load_for_releases
 {
     my ($self, @releases) = @_;
@@ -89,6 +111,7 @@ sub load_for_releases
         }
     }
 
+    $self->load_track_durations(@mediums);
     $_->mediums_loaded(1) for @releases;
 }
 

lib/MusicBrainz/Server/Edit/Medium/SetTrackLengths.pm

@@ -100,6 +100,7 @@ sub initialize {
     $self->c->model('Release')->load($medium);
     $self->c->model('ArtistCredit')->load($medium->release);
     $self->c->model('Track')->load_for_mediums($medium);
+    $self->c->model('Medium')->load_track_durations($medium);
 
     my $cdtoc = $self->c->model('CDTOC')->get_by_id($cdtoc_id);
 

lib/MusicBrainz/Server/Entity/Medium.pm

@@ -132,17 +132,23 @@ has 'cdtoc_track_count' => (
 
 has 'cdtoc_track_lengths' => (
     is => 'rw',
-    isa => 'ArrayRef[Maybe[Int]]'
+    isa => 'Maybe[ArrayRef[Maybe[Int]]]'
 );
 
 has 'data_track_lengths' => (
     is => 'rw',
-    isa => 'ArrayRef[Maybe[Int]]'
+    isa => 'Maybe[ArrayRef[Maybe[Int]]]'
 );
 
 has 'pregap_length' => (
     is => 'rw',
-    isa => 'ArrayRef[Maybe[Int]]'
+    isa => 'Maybe[ArrayRef[Maybe[Int]]]'
+);
+
+has 'durations_loaded' => (
+    is => 'rw',
+    isa => 'Bool',
+    default => 0,
 );
 
 sub audio_tracks {

lib/MusicBrainz/Server/Entity/MediumCDTOC.pm

@@ -33,7 +33,7 @@ sub is_perfect_match {
     my ($self) = @_;
 
     my @cdtoc_info = @{ $self->cdtoc->track_details };
-    my @medium_track_lengths = @{ $self->medium->cdtoc_track_lengths };
+    my @medium_track_lengths = @{ $self->medium->cdtoc_track_lengths // [] };
 
     return (@cdtoc_info == @medium_track_lengths) && all {
       defined $_->[1] && $_->[0]{length_time} == $_->[1]

t/lib/t/MusicBrainz/Server/Data/DurationLookup.pm

@@ -126,7 +126,7 @@ test 'TOC lookup for disc with pregap track' => sub {
     my $medium = $c->model('Medium')->get_by_id($created->{id});
     isa_ok($medium, 'MusicBrainz::Server::Entity::Medium');
 
-    $c->model('Track')->load_for_mediums($medium);
+    $c->model('Medium')->load_track_durations($medium);
     is($medium->length, 1122 + 330160, "inserted medium has expected length");
 
     my ($durationlookup, $hits) = $c->model('DurationLookup')->lookup("1 1 39872 15110", 1);

t/lib/t/MusicBrainz/Server/Data/Medium.pm

@@ -54,6 +54,7 @@ test 'Insert medium' => sub {
     my $medium = $c->model('Medium')->get_by_id($created->{id});
     isa_ok($medium, 'MusicBrainz::Server::Entity::Medium');
 
+    $c->model('Medium')->load_track_durations($medium);
     is($medium->length, 330160 + 262000, "inserted medium has expected length");
 
     my $trackoffset0 = 150;